skip to main |
skip to sidebar
Pet related:
# show Prowl
/cast Freezing Trap
/use Filtered Draenic Wate/use Sunspring Carp
/cast Shadowmeld
/cast Prowl
What it does?
1. Drop Frost Trap
2. Eat/Drink (need to specify the items)
3. Shadowmeld/Prowl you and your Cat
-----------------------------------------------------
/cast [nopet] Call Pet;[target=pet,dead]Revive Pet
/clearfocus [target=focus,dead]
/focus [target=focus,exists]player;target
/clearfocus [target=focus,noharm]
/petattack [target=focus,exists]
/petfollow [target=focus,noexists]
/cast Hunter's Mark
What it does?
1. If your pet is dead: You will cast Revive Pet
2. If your pet is not summoned: You will cast Call Pet.
3. If you are not focused: You will focus on your target and your pet will be sent to attack it.
4. If you are focused: You will clear focus and your pet will be recalled to follow you.
5. Hunter's Mark will be cast on the target
-----------------------------------------------------
/cast [nocombat] Feed Pet; [combat] Mend Pet
/use [nocombat]
(feed food by name)
OR
/cast [combat] Mend Pet; [nocombat] Feed Pet
/use [nocombat] 1 13
(Feed by bag slot: bag #1 slot #13)
OR
/cast [pet, nocombat] Feed Pet
/use [pet:Cat/Ravager, nocombat] ; [pet:Wind Serpent, nocombat]
(Feed a certain food item depending on the type of pet)
OR
#show
/cast [modifier:alt][combat] Mend Pet; [pet, nocombat] Feed Pet
/use [pet, nocombat, nomodifier:alt]
(Hold down alt to cast Mend Pet out of combat, and shows the amount of food you have in your bags)
-----------------------------------------------------
/focus [target=pettarget,modifier:shift]
/petfollow [nomodifier:shift]
/petattack
/target [modifier:shift] focus
/petattack [modifier:shift]
What it does?
This acts like a normal pet attack button, but when you hold shift and use it, your pet will attack your current target only once it is done killing all its already queued targets.
OR
/focus [target=pettarget,modifier:shift]
/petfollow [nomodifier:shift]
/petattack [target=mouseover,modifier:shift]
/petattack
/target [modifier:shift] focus
/petattack [modifier:shift]
What it does?
Activates the queue with a simple mouseover of the next target you wish your pet to attack.
This saves you from changing between targets while shooting down another mob.
-----------------------------------------------------
/cast [modifier] Revive Pet; [target=pet,dead] Revive Pet; [nopet] Call Pet; Mend Pet
What it does?
This will revive your pet if it's dead, call your pet if you don't have him out, or mend your pet.
-----------------------------------------------------
/cast [nopet] Call Pet; Revive Pet
What it does?
This macro will call your pet if you do not have one, otherwise it attempts to cast Revive Pet.
-----------------------------------------------------
#showtooltip
/cast [nopet,modifier] Revive Pet; [target=pet,dead] Revive Pet; [nopet] Call Pet; [combat][modifier]Mend Pet
/stopmacro [combat]
#showtooltip Feed Pet
/cast Feed Pet
/use
OR reversed one:
#showtooltip [nopet,mod][target=pet,dead] Revive Pet; [nopet] Call Pet; [mod] ; Mend Pet
/cast [nopet,mod][target=pet,dead] Revive Pet; [nopet] Call Pet; [modifier] Feed Pet; Mend Pet
/use [modifier]
What it does?
1. This macro calls your pet if he's not out.
2. Revives him if he's dead.
3. Heals him during combat.
4. Feeds him out of combat.
Since the macro system can't tell whether your pet is alive if his corpse isn't around, holding any modifier when you have no pet out will cast Revive Pet. Also, holding any modifier key when your pet is out will heal him instead of feeding.
-----------------------------------------------------
/castsequence reset=15 Mend Pet, null
What it does?
1. This macro will cast Mend Pet, but only if it has not been used in the last 15 seconds.
2. Effectively it will avoid waste of mana from accidentally casting one Mend Pet over the other.
3. If you bind it to a button, the button will be greyed out while the macro is in "hold mode".
OR
#showtooltip
/cast [modifier:shift] Mend Pet(Rank 1); Mend Pet
What it does?
This macro provides one button for those Hunters with the Improved Mend Pet talent.
Often, you will want to simply dispel your pet, rather than spend the mana of a full Mend Pet.
This macro will cast your highest rank Mend Pet by default, and cast rank 1 if holding down the shift key (Feel free to change the key to your liking).
Read more...
General Utility Macros 
Faerie Fire / Faerie Fire (Feral)
#showtooltip
/cast [nostance] Faerie Fire; Faerie Fire (Feral)()
Mark of the Wild / Gift of the Wild
#showtooltip Gift of the Wild
/cast [button:2] [modifier] Gift of the Wild; Mark of the Wild
Thorns > Mark of the Wild > Omen of Clarity
#showtooltip
/castsequence [modifier, target=player] [help] [target=player] reset=10/target Thorns, Mark of the Wild, Omen of Clarity
{note: Thorns is first because you have to refresh it more often}
Prowl / Shadowmeld (Night Elf) (sticky)
/cast [nocombat, stance:3, nostealth] Prowl; [nocombat, nostealth] Shadowmeld
War Stomp > Regrowth > Rejuvenation (Tauren)
#showtooltip War Stomp
/cancelform
dismount
/castsequence [target=player] reset=120/combat War Stomp, Regrowth, Rejuvenation
{also: replace Regrowth/Rejuvenation with "Healing Touch" or "Nature's Swiftness; /stopcasting; /cast [target=player] Healing Touch"}
Bear Form > Bash > Regrowth > Rejuvenation > Bear Form
#showtooltip
/cancelform [nostance:1]
/castsequence [stance:1] reset=9 Bash,Dire Bear Form;[nostance,target=player] reset=9 Dire Bear Form,Regrowth,Rejuvenation
{also: replace Regrowth/Rejuvenation with "Healing Touch" or "Nature's Swiftness, Healing Touch" (takes 2 clicks)}
Caster Form > Health Pot > Rejuvenation > Regrowth > Healing Touch
/cancelform
/castsequence [nostance, target=player] Major Healing Potion, Rejuvenation, Regrowth, Healing Touch
{note: this sequence will not run at all while healing potions are on cooldown}
{also: try "/castsequence [nostance, target=player, modifier] Major Healing Potion, Rejuvenation, . . .; [nostance, target=player] Rejuvenation, . . ."}
Caster Form > Barkskin > Tranquility
/stopmacro [channeling:Tranquility]
/cancelform
/castsequence [nostance] reset=60 Barkskin, Tranquility
{also: to shift to Bear Form after, add ", Dire Bear Form" at the end}
{also: to prevent deshifting from Tree of Life, add "[nostance:5]" after the /cancelform}
Bash / Cower > Caster Form > Barkskin > Tranquility / Rebirth
/cast [stance:1] Bash; [stance:3] Cower
/cancelform
/castsequence [target=mouseover,dead] [dead] reset=55 Barkskin, Rebirth; reset=55 Barkskin, Tranquility
Read more...
Restoration Macros
Remove Curse
/cast [target=mouseover, help] [target=targettarget, help] [target=player] Remove Curse
Cure Poison
/cast [target=mouseover, help] [target=targettarget, help] [target=player] Cure Poison
Abolish Poison / Remove Curse
/cast [modifier, target=mouseover, help] [button:2, target=mouseover, help] Remove Curse; [button:1, target=mouseover, help] Abolish Poison
Cure Poison / Remove Curse (spamable)
/targetfriend
/cast [modifier] [button:2] Remove Curse; [button:1] Cure Poison
/stopcasting
Cure Poison + Remove Curse (spamable) (unconfirmed)
/targetfriend
/cast Cure Poison
/stopcasting
/cast Remove Curse
/stopcasting
Cure Poison + Remove Curse (unconfirmed)
/cast [target=mouseover, help] Cure Poison
/stopcasting
/cast [target=mouseover, help] Remove Curse
"Pseudo-Decursive" (unconfirmed)
/cast [help] Cure Poison
/stopcasting
/cast [target=player] Cure Poison
/cast [target=party1] Cure Poison
/cast [target=party2] Cure Poison
/cast [target=party3] Cure Poison
/cast [target=party4] Cure Poison
/stopcasting
Nature's Swiftness + Healing Touch
/cast Nature's Swiftness
/stopcasting
/cast [help] [target=player] Healing Touch
Caster Form > Nature's Swiftness + Healing Touch
/cancelform
/cast [nostance] Nature's Swiftness
/stopcasting
/cast [nostance, help] [nostance, target=player] Healing Touch
Caster Form > Rejuvenation > Swiftmend
/cancel [nostance:5]
/castsequence [nostance] Rejuvenation, Swiftmend
{also: add "Barkskin" and/or "Regrowth" before the Rejuvenation}
Nature's Swiftness + Healing Touch / Regrowth (in Tree of Life)
/cast Nature's Swiftness
/stopcasting
/cast [nostance, help] [nostance, target=player] Healing Touch; [stance:5, help] [stance:5, target=player] Regrowth
Trinket + Nature's Swiftness + Healing Touch / Regrowth
/use Zandalarian Hero Charm
/stopcasting
/cast Nature's Swiftness
/stopcasting
/cast [nostance, help] [nostance, target=player] Healing Touch; [stance:5, help] [stance:5, target=player] Regrowth
Healing Touch (target or target's target)
/cast [help] [target=targettarget] Healing Touch
Healing Touch (every situation)
/cast [modifier,target=player] [help] [target=targettarget, help] [target=mouseover,help] [target=focus,help] [target=focustarget,help] [target=none] Healing Touch
Healing Touch + Equip Idol
/cast Healing Touch
/equip Idol of the Avian Heart
Healing Touch & Announce (Say)
/cast [help] Healing Touch; [target=player] Healing Touch
/stopmacro [nohelp]
/say "Healing %t in 3 seconds."
Rejuv + Equip Idol
/equip Idol of Rejuvenation
/cast Rejuvenation
{note: this takes two clicks due to the GCD on swapping idols in combat}
Regrowth > Rejuvation > Lifebloom
/castsequence [help] [target=player] reset=8/target Regrowth, Rejuvenation, Lifebloom
Rebirth
#showtooltip
/cast [help, dead] [target=targettarget, help, dead] [target=mouseover, help, dead] [target=focus, help, dead] Rebirth; [target=focustarget, help, dead] [target=none] Rebirth
Rebirth & Announce (Channel)
/stopmacro [nohelp]
/stopmacro [help, nodead]
/5 <>
/cast Rebirth
Rebirth / Innervate & Smart Announce
/run u="mouseover"s=UnitIsDead(u)and"Rebirth"or"Innervate"t,d=GetSpellCooldown(s)IsSpellInRange(s,u)==1 and d<=GetTime()-t and SendChatMessage("Casting "..s.." on "..UnitName(u),"PARTY")
/cast [target=mouseover,nodead]Innervate;[target=mouseover]Rebirth
Read more...
Feral Macros
Cat Macros
{also: to combine with non-cat macros, add "[stance:3]" in every /cast line}
Faerie Fire / Prowl
/cast [combat, nostealth] Faerie Fire (Feral)(); [nocombat, nostealth] Prowl
{note: the extra () is necessary}
Mangle > Cower / Faerie Fire
/castsequence [nomodifier] reset=target Mangle (Cat)(Rank 3), Mangle (Cat)(Rank 3), Mangle (Cat)(Rank 3), Cower
/cast [modifier] Faerie Fire (Feral)()
{note: the (Rank N) is necessary, change to your own rank}
Mangle / Ferocious Bite {also: Rip / Faerie Fire}
#showtooltip
/cast [modifier] Ferocious Bite; Mangle (Cat)()
{also: replace Ferocious Bite with "Rip" or ""Faerie Fire (Feral)()"}
Mangle / Shred
/castrandom [stance:3] Mangle (Cat)(), Shred, Shred
Pounce / Mangle
/cast [nostealth] Mangle (Cat)(); [stealth] Pounce
Pounce / Mangle / Ferocious Bite {also: Rip / Faerie Fire}
#show Mangle (Cat)()
/cast [modifier] Ferocious Bite; [stealth] Pounce; Mangle (Cat)()
{also: replace Ferocious Bite with "Rip" or ""Faerie Fire (Feral)()"}
Pounce / Mangle > Rake
/castsequence [nostealth] reset=4/target/combat Mangle (Cat)(Rank 3), Rake, Mangle (Cat)(Rank 3), Mangle (Cat)(Rank 3), Mangle (Cat)(Rank 3)
/cast [stealth] Pounce
Pounce / Rake
/cast [nostealth] Rake; [stealth] Pounce
Pounce / Rake / Rip
#show Rake
/cast [modifier] Rip; [stealth] Pounce; Rake
Pounce / Mangle > Rake / Ferocious Bite
/castsequence [nostealth, nomodifier] reset=4/target/combat Mangle (Cat)(Rank 3), Rake, Mangle (Cat)(Rank 3), Mangle (Cat)(Rank 3), Mangle (Cat)(Rank 3)
/cast [modifier] Ferocious Bite; [stealth] Pounce
{also: replace Ferocious Bite with "Rip" or ""Faerie Fire (Feral)()"}
Prowl / Pounce
/cast [nostealth, nocombat] Prowl; [stealth] Pounce
Prowl / Pounce / Faerie Fire > Mangle > Shred
/castsequence [nostealth, combat] reset=6/target/combat Faerie Fire (Feral)(Rank 5), Mangle (Cat)(Rank 3), Shred
/cast [nostealth, nocombat] Prowl; Pounce
{also: replace Shred with "Rake"}
Ravage / Shred
/cast [nostealth] Shred; [stealth] Ravage
Ravage / Shred / Ferocious Bite
#show Shred
/cast [modifier] Ferocious Bite; [stealth] Ravage; Shred
{also: replace Ferocious Bite with "Rip" or ""Faerie Fire (Feral)()"}
Tiger's Fury > Ravage / Shred
#show Shred
/cast [stealth] Tiger's Fury
/stopcasting
/cast [stealth] Ravage; Shred
{also: alternate method- "/castsequence [stealth] reset=6 Tiger's Fury, Ravage"}
Trinket > Ravage / Shred
/use Bladefist's Breadth
/stopcasting
/cast [stealth] Ravage; Shred
Trinket1 / Trinket2 > Ravage
/use Bladefist's Breadth
/stopcasting
/use Terokkar Tablet of Precision
/stopcasting
/cast [stealth] Ravage; Shred
{note: the second trinket will only activate if the first trinket fails, but the spell will always cast}
Find Minerals > Find Herbs > Track Humanoids
/castsequence Find Minerals, Find Herbs, Track Humanoids
Prowl + Change Actionbar
/cast [nocombat, nostealth] Prowl
/changeactionbar [stance:3, nocombat] 2
{also: try replacing the nocombat condition in /changeactionbar with "stealth" if you occasionally end up in combat and in stealth without the new actionbar - this may require 2 clicks}
Unstealth + Change Actionbar
/cast [stealth] Pounce
/changeactionbar 1
{also: make a similar macro using "/cast [stealth] Ravage"}
{also: try adding "[nostealth]" condition in /changeactionbar if you occasionally end up out of stealth without the main actionbar - this may require 2 clicks}
(note: you need a mod to switch actionbars based on an event change like unstealthing. macros must be tied to button clicks}
"Update Stealth/Unstealth Actionbar"
/changeactionbar [nostealth] 1; [stealth] 2
{also: to tie this with an actual ability, consider adding "/cast Tiger's Fury" somewhere}
(note: you need a mod to switch actionbars based on an event change like unstealthing. macros must be tied to button clicks}
Maim > Regrowth > Rejuvenation > Cat Form
/castsequence [stance:3] reset=10 Maim,Cat Form; [nostance,target=player] reset=10 Regrowth,Rejuvenation,Cat Form
{also: to use this macro to heal others, include "[nostance,target=targettarget,help] reset=10 Regrowth,Rejuvenation,Cat Form; " and/or "[nostance,target=mouseover,help] reset=10 Regrowth,Rejuvenation,Cat Form; " before the last sequence}
{also: replace Regrowth/Rejuvenation with "Healing Touch" or "Rejuvenation, Swiftmend" if you have it}
Caster Form > Potion > Cat Form *new*
/castsequence reset=3 Cat Form, Enrage
/stopcasting
/use
{note: Enrage is used to prevent accidental double-shifting by stopping the castsequence from reaching the end and resetting - any spell/item that will always fail can be used}
Bear Macros
{also: to combine with non-bear macros, add "[stance:1]" in every /cast line}
Demo Roar / Bash
/cast [modifier] Bash; Demoralizing Roar
Enrage + Feral Charge
/cast Enrage
/stopcasting
/cast Feral Charge
Feral Charge / Bash {aslo: Mangle / Lacerate / Growl}
/cast Feral Charge
/stopcasting
/cast Bash
{also: replace Bash with "Mangle (Bear)()" or "Lacerate" or "Growl"}
Lacerate
#showtooltip
/cast [target=mousever, harm] [harm] Lacerate
Maul + auto-attack
#showtooltip Maul
/startattack [nomodifier]
/cast [nomodifier] Maul
/stopattack [modifier]
{note: holding a modifier key will allow you to stop attacking}
Maul + Faerie Fire
/cast Maul
/cast Faerie Fire (Feral)()
Maul + Faerie Fire + auto-attack & Hide Errors
#showtooltip
/stopattack [modifier]
/stopmacro [modifier]
/startattack
/cast Maul
/script UIErrorsFrame:Hide()
/cast Faerie Fire (Feral)()
/script UIErrorsFrame:Clear(); UIErrorsFrame:Show()
Maul + Feral Charge
/cast Maul
/cast Feral Charge
{note: this cannot be done with the rage from Furor alone}
Maul + Mangle
#showtooltip Mangle (Bear)()
/cast Maul
/cast Mangle (Bear)()
{also: to hide the errors when spamming the macro while Mangle is on cooldown, add "/script UIErrorsFrame:Hide()" before the Mangle line, and "/script UIErrorsFrame:Clear(); UIErrorsFrame:Show()" after}
Maul > Mangle
/castsequence reset=5/combat Maul, Mangle (Bear)(Rank 3), Maul, Maul
Maul / Mangle / Faerie Fire
/castrandom Faerie Fire (Feral)(), Mangle (Bear)(), Mangle (Bear)(), Maul, Maul, Maul
Maul + Faerie Fire > Mangle
/cast Maul
/castsequence reset=6/target/combat Faerie Fire (Feral)(Rank 5), Mangle (Bear)(Rank 3)
"Bear Opener"
#showtooltip
/startattack
/castsequence [nocombat] Enrage, Feral Charge;[combat] reset=30 Faerie Fire (Feral)(Rank 5), Demoralizing Roar, Maul, Mangle (Bear)(Rank 3), Maul, Swipe, Maul
"Buffed Pull"
/castsequence [nostance, target=player] reset=target/combat Regrowth, Rejuvenation, Barkskin, Bear Form
/cast [stance:1] Feral Charge
Moonfire > Bear Form / Faerie Fire
/startattack
/castsequence [nostance] reset=combat Moonfire, Dire Bear Form; [stance:1] Faerie Fire (Feral)()
{also: insert "Starfire, " before Moonfire}
Bash > Regrowth > Rejuvenation > Bear Form
/castsequence [stance:1] reset=60 Bash, Dire Bear Form; [nostance, target=player] reset=60 Regrowth, Rejuvenation, Dire Bear Form
{also: replace Regrowth/Rejuvenation with "Healing Touch" or "Rejuvenation, Swiftmend" if you have it}
Bash > Nature's Swiftness > Healing Touch > Bear Form
/castsequence [stance:1] reset=60 Bash, Dire Bear Form
/cast [nostance] Nature's Swiftness
/stopcasting
/castsequence reset=10 [nostance, target=player] Healing Touch, Dire Bear Form
{also: to use this macro to heal others, include "[nostance,target=targettarget,help] reset=10 Healing Touch,Dire Bear Form; " and/or "[nostance,target=mouseover,help] reset=10 Healing Touch,Dire Bear Form; " before the last sequence}
Caster Form > Potion > Bear Form
/castsequence reset=3 Dire Bear Form, Cower
/stopcasting
/use
{note: Cower is used to prevent accidental double-shifting by stopping the castsequence from reaching the end and resetting - any spell/item that will always fail can be used}
Read more...
Balance Macros
Barkskin > Hurricane
/stopmacro [channeling:Hurricane]
/castsequence reset=55/combat Barkskin, Hurricane
Entangling Roots / Nature's Grasp
/cast [modifier] Nature's Grasp; [nostance, harm] [stance:5, harm] Entangling Roots; Nature's Grasp
Faerie Fire
/cast [harm] [target=targettarget, harm] Faerie Fire
Innervate
/cast [modifier, target=player] [help] [target=mouseover, exists, help] [target=none] Innervate
{note: Innervate cannot be used on units that do not have a mana bar}
Innervate & Announce (Channel)
/cast [help] Innervate
/stopmacro [nohelp]
/5 <>
/script SendChatMessage("You have been INNERVATED, use it well!","WHISPER",nil, UnitName("target"))
Innervate & Smart Whisper
/run local s,u="Innervate","target";local t,d=GetSpellCooldown(s);if IsSpellInRange(s,u)==1 and UnitManaMax(u)>120 and d<=GetTime()-t then SendChatMessage("You have been INNERVATED!","WHISPER",nil,UnitName(u))end
/cast [help,nodead]Innervate
{also: change "target" to "mouselook"}
{also: you can remove each "local" for more space}
Innervate & Smart Whisper & Raid
/run s,u="Innervate","target"t,d=GetSpellCooldown(s)if IsSpellInRange(s,u)==1 and UnitManaMax(u)>120 and d<=GetTime()-t then SendChatMessage("You're INNERV8D","WHISPER",nil,UnitName(u))SendChatMessage(UnitName(u).."'s INNERV8D","RAID")end
/cast Innervate
Moonfire (spamable)
/castsequence reset=9/target/combat/ctrl Moonfire(Rank 12), Moonfire(Rank 11), Moonfire(Rank 11), Moonfire(Rank 11), Moonfire(Rank 11), Moonfire(Rank 11)
Moonfire (various ranks)
/cast [modifier:ctrl] Moonfire(Rank 1); [button:2] Moonfire(Rank 11); Moonfire(Rank 12)
Moonfire & Equip Idol
/equip Idol of the Moon
/cast Moonfire
{note: this takes two clicks due to the GCD on swapping idols in combat}
"Totem Killer"
/focus target
/targetenemy
/cast [harm] Moonfire(Rank 1)
/target focus
Starfire / Moonfire > Insect Swarm > Wrath
/cast [nocombat] Starfire
/castsequence reset=12/target Moonfire, Insect Swarm, Wrath, Wrath, Wrath, Wrath
{also: add "Entangling Roots, " after Insect Swarm}
Cyclone > Regrowth > Rejuvenation / Bandage
/castsequence [nostance] reset=12 Cyclone, Regrowth, Rejuvenation; [stance:5] reset=30 Cyclone, Heavy Netherweave Bandage
Cyclone > Caster Form > Regrowth > Rejuvenation > Moonkin Form > Starfire
/castsequence [stance:5] reset=12 Cyclone, Moonkin Form, Starfire; [nostance, target=player] reset=12 Regrowth, Rejuvenation, Moonkin Form
{also: replace Regrowth/Rejuvenation with "Healing Touch" or "Rejuvenation, Swiftmend" if you have it}
{also: the sequence involving Starfire can be extended with the Moonfire > Insect Swarm > Wrath sequence}
Read more...
Copying Macros
When copying macros from this guide, you might get code with the # sign in front of each line. You must remove the # sign in order for the macro to work, because WoW treats lines with the # sign as comments.
To copy macros from one computer to another, copy the macros-cache.txt on your computer to the exact same location in the new computer. Account-wide macros are usually found at ..\World of Warcraft\WTF\Account\\macros-cache.txt, and character-specific macros are at ..\World of Warcraft\WTF\Account\\\\macros-cache.txt.
Shifting Cooldown
The "shifting cooldown" only applies when you are trying to deshift within the first 1.5 seconds of shifting into that form, using the special action buttons. It does not stop you from instantly shifting from one form into another (using those buttons), and it does not apply to macros.
NOTE: This can be turned off by unchecking the Secure Ability Toggle at the top of the Basic Interface Options menu.
While there is no Global Cooldown when shifting out of a form (GCD is only when shifting into forms), there is nonetheless a brief delay as the server/client recognizes the change in form. This latency delay is what prevents you from using abilities in your new form (such as casting) in the same instant you deshift.
NOTE: If you are experiencing a GCD when deshifting, it is almost certainly because you have a mod or macro automatically swapping weapons/idols while you are in combat.
Macro Legend of Symbols
Spell1 / Spell2 = Either Spell1 or Spell2
Spell1 > Spell2 = Spell1 then Spell2 on next click
Spell1 + Spell2 = Spell1 and Spell2 in a single click
Spell1 & Spell2 = Any other kind of combination of Spell1 and Spell2
"Name" = Nickname in place of description of macro behavior
= Replace with either Moonkin Form or Tree of Life depending upon your spec
[stance:5?6] = Replace "5?6" with 6 if specced for Moonkin Form or Tree of Life, and with 5 otherwise
(spamable) = Can be cast over and over, or it swaps between two states
(sticky) = Macro cannot immediately be reactivated regardless of clicking, or end state is static
(unconfirmed) = Macro might not work the way it's intended to
{also: . . . } = Alternate suggestion for minor changes
{note: . . . } = Explanation or tip
NOTE: All shifting macros work from any form
Macro Guide
NO macro can cast spells based on: BUFFS, DEBUFFS, COOLDOWNS, or TARGET DISTANCE
NO macro can cast spells based on: HEALTH, MANA, RAGE, ENERGY, or COMBO POINTS
Any failed cast attempt stops the macro from casting any further spells
* Except for spells that do not invoke the Global Cooldown (GCD)
/cast Spell - casts Spell on your target
* Spells will automatically reduce rank if the target is too low a level
* Spells written without "(Rank N)" will automatically cast the highest rank you know
* NOTE: Spells with parentheses as part of their name require extra "()" after, e.g.:
/cast Faerie Fire (Feral)() or /cast Mangle (Bear)()
/cast [condition] Spell - casts Spell when condition is true. condition can be:
* help/harm - Choose depending on whether target is assistable or attackable
* combat - Choose depending on whether you're in combat
* stance or stance:# - Choose depending on your stance/shapeshift ("stance" alone matches any stance)
stance:1 is (Dire) Bear Form
stance:2 is Aquatic Form
stance:3 is Cat Form
stance:4 is Travel Form
stance:5 is Moonkin Form or Tree of Life (if talent points spent), or Flight Form
stance:6 is Flight Form if you already have Moonkin Form or Tree of Life
NOTE: Numbers may be different if you are missing earlier forms
* stealth - Choose depending on whether you are stealthed
* mounted - Choose depending on whether you are mounted
* swimming - Choose depending on whether you are swimming
* flying - Choose depending on whether you are flying
* flyable - Choose depending on whether you are able to use Flight Form / flying mount
* indoors - Choose depending on whether you are indoors
* outdoors - Choose depending on whether you are outdoors
* modifier or modifier:shift/ctrl/alt - Choose depending on any modifier keys you're holding at the time the macro runs
* equipped:InvSlot#|ItemClass|ItemSubclass - Choose if you have the specific item type equipped
* actionbar:Bar# - Choose if a specific actionbar is shown
* button:Z - Choose if the specified button is held down
* pet:Name|Family - Choose if your current active pet has the specified name or family (e.g. pet:bear/wolf)
* channeling or channeling:Spell - Choose if you are channeling (possibly a specific spell)
* exists - Choose if the target exists
* dead - Choose if the target is dead
* party - Choose if target is in your party
* raid - Choose if target is in your raid
* group:party/raid - Choose if you are in a party or raid
* Any condition can be prefixed with "no" to select if it does NOT match
/cast [target=unit] Spell - casts Spell on unit without changing your target. unit can be:
* player (yourself), target, focus, mouseover, pet, PlayerName, or none
* target=unit is not actually a condition
* target=unit forces other conditions to evaluate using unit instead of the real target
* NOTE: target=none will function as if you had no unit selected, giving you the "glowing hand" selector (unless you have enabled auto self-cast?)
* Any unit can be followed by "target" to designate that unit's target, e.g.:
targettarget, pettarget, or PlayerName-target (note extra "-")
/cast [condition1a, condition1b] Spell1; [condition2a] [condition2b] Spell2; Spell3 - casts Spell1 when both condition1a and condition1b are true, or Spell2 when either condition2a or condition2b is true, and Spell3 anytime else, e.g.:
* /cast [stealth] Pounce; [nocombat, nostealth] Prowl; [modifier:ctrl] Rip; Mangle (Cat)()
* Separate multiple conditions with " , " (comma)
* Separate multiple casting choices with " ; " (semicolon)
/castsequence reset=event Spell1, Spell2, Spell3, etc. - casts Spell1 then Spell2 on next click, then Spell3, and so forth
* castsequence will not advance to the next spell until the current spell is successfully cast
* The sequence maintains state (the current spell awaiting cast) until it is reset, even if a requisite condition becomes false
* The sequence always resets after casting the final spell, and also when event occurs ("reset=event" is optional)
But you can prevent the sequence from automatically resetting at the end by ending with a spell that will always fail, or by repeating the last spell several times
* event can be: N (seconds), target (when target changes), combat, shift, alt, and/or ctr
* Separate multiple reset events with " / "
* Supports spells and items and slot numbers and bag slot numbers
* NOTE: Spells with parentheses as part of their name ALWAYS require "(Rank N)", e.g.:
/castsequence Faerie Fire (Feral)(Rank 4), Maul, Mangle (Bear)(Rank 3), Swipe
NOT: /castsequence Faerie Fire (Feral)()
/cancelaura [condition] Buff - cancels a Buff as if it were right-clicked, e.g.:
* /cancelaura [stance:2] Aquatic Form; [stance:3] Cat Form; [stance:4] Travel Form
* The above macro cancels Aquatic, Cat, and Travel Form, returning you to caster form
* It does nothing while in Bear Form because "[stance:1] Dire Bear Form;" is missing
* With /cast [nostance] Dire Bear Form, the macro shifts you into Bear Form, but never out
* This shifting behavior is known as "sticky"
/cancelform [condition] - cancels any form you are in, subject to the condition, e.g.:
* /cancelform [nostance:1] - cancels every form except for Bear Form (same as the above /cancelaura line)
#show and #showtooltip - display cooldown (and tooltip) of next Spell or Item or Inventory Slot# or Backpack Slot# over the macro's icon
* The question mark icon [?] will copy the spell's original graphic
* The question mark icon [?] will dynamically update with each spell in a castsequence or change in condition (NEW)
* Conditions can also be used directly in the #show and #showtooltip lines, e.g.:
#show [nostance] 13; [stance:3, nocombat] Prowl
/focus unit - allows you to "store" a target until you clear the focus (with /clearfocus), which can be targetted at any time (with /target focus, or [target=focus])
Other "slash commands" include:
* Targeting: /targetlasttarget, /cleartarget, /focus, /clearfocus
* Target Cycling: /targetenemy, /targetfriend, /targetparty, /targetraid - All work using the TargetNearest* API's and enemy/friend may only be called once per macro. An optional argument of '1' can be used to reverse direction.
* Items and equipment: /use ItemName, /use Slot#, /use BagID# BagSlot#, /equip ItemName or ItemID#, /equipslot Slot# ItemName, /userandom Item1, Item2, Item3 will attempt to use a randomly selected one of the specified items
* Pet control: /petattack, /petfollow, /petstay, /petpassive, /petdefensive, /petaggressive, /petautocaston Spell, /petautocastoff Spell
* Casting: /stopcasting will cancel the spell that is currently being cast, /castrandom Spell1, Spell2, Spell3 will attempt to cast a randomly selected one of the specified spells
* Action bar: /changeactionbar Bar# and /swapactionbar Bar1# Bar2#
* Attacking: /startattack unit ("unit" is optional), /stopattack
* Buffs/Auras: /cancelaura name - cancels an aura as if it were right clicked
* Buttons: /click ButtonNameMouseButton# ("MouseButton#" is optional)
* Macros: /stopmacro
* Dismounting: /dismount - note that the default UI now automatically dismounts you upon casting
Tips to shrink macro length to fit within 255 character limit
* Remove spaces around any punctuation (" [ ] = , ; ")
* ItemName only needs enough text to make the item unique
Read more...
Druid Shifting Macros
Caster Form (sticky)
/cancelform
{note: /dismount is no longer necessary as the default UI now automatically dismounts you upon casting}
Dire Bear Form (sticky)
/cancelform [nostance:1]
/cast [nostance] Dire Bear Form
{also: to make this spamable, remove "[nostance:1]" from the /cancelform line}
Dire Bear Form > Feral Charge (sticky)
/cancelform [nostance:1]
/cast [nostance] Dire Bear Form; [stance:1] Feral Charge
{also: to make this spamable, change /cast line to "/castsequence [nostance] Dire Bear Form; [stance:1] reset=15 Feral Charge, Dire Bear Form"}
Dire Bear Form > Feral Charge / Bash (sticky)
/cancelform [nostance:1]
/cast [nostance] Dire Bear Form; [stance:1] Feral Charge
/stopcasting
/cast [stance:1] Bash
Dire Bear Form + Equip Idol + Weapon
/cancelform [nostance:1]
/cast [nostance] Dire Bear Form
/equip [nostance] Earthwarden
/equip [nostance] Idol of Brutality
{note: the equip condition is still [nostance] because it hasn't yet registered that the stance has changed. equipping gear in combat can be done during a global cooldown, but it also causes a GCD, so you cannot shift after equipping}
Cat Form (sticky)
/cancelform [nostance:3]
/cast [nostance] Cat Form
{also: to make this spamable, remove "[nostance:3]" from the /cancelform line}
Cat Form > Prowl (sticky)
#show Prowl
/cancelform [nostance:3]
/cast [nostance] Cat Form; [stance:3, nocombat, nostealth] Prowl
Cat Form > Prowl > Pounce > Mangle
#showtooltip
/cancelform [nostance:3]
/cast [nostance] Cat Form; [stance:3, nostealth, nocombat] Prowl; [nostealth, combat] Mangle (Cat)(); [stealth] Pounce
Cat Form + Equip Idol + Weapon
/cancelform [nostance:3]
/cast [nostance] Cat Form; [stance:3, nostealth] Prowl
/equip [nostance] Idol of Ferocity
/equip [nostance] Staff of the Wild
{note: the equip condition is still [nostance] because it hasn't yet registered that the stance has changed. equipping gear in combat can be done during a global cooldown, but it also causes a GCD, so you cannot shift after equipping}
Travel Form (sticky)
/cancelform [nostance:4]
/cast [nostance] Travel Form
{also: to make this spamable, remove "[nostance:4]" from the /cancelform line}
Travel Form / Aquatic Form (sticky)
/canceform [nostance:2, nostance:4]
/cast [nostance, swimming] Aquatic Form; [nostance, outdoors] Travel Form
{also: to make this spamable, remove "[nostance:2, nostance:4]" from the /cancelform line}
Travel Form / Aquatic Form / Mount (sticky)
/cancelform [nostance:2, nostance:4] [stance:4, nocombat]
/use [nostance, nomounted, outdoors, nocombat]
/cast [nostance, swimming] Aquatic Form; [nostance, outdoors] Travel Form
{also: to make this spamable, remove "[nostance:2, nostance:4]" from the /cancelfrom line}
{also: to have more control over when you mount, add "modifier" inside the /use line condition list, and add "/dismount" to the top}
Flight Form (sticky)
/cancelform [nostance:5?6]
/cast [nostance] Flight Form
{also: to make this spamable, remove "[stance:5?6]" from the /cancelfrom line, where 5?6 is 5 or 6 depending on talent spec}
Flight Form / Travel Form / Aquatic Form (sticky)
/cancelform [stance:1/3] [stance:4, flyable, nocombat]
/cast [nostance, swimming] Aquatic Form; [nostance, flyable, nocombat] Flight Form; [nostance, outdoors] Travel Form
{also: if you have Moonkin Form or Tree of Life, replace "[stance:1/3]" with "[stance:1/3/5]"}
{also: for spamming, remove "[stance:1/3]" from the /cancelform line}
{also: for spamming only while flying (for quick descent), add "[stance:5?6, nocombat]" to the /cancelform line}
{note: this will take you out of Travel Form if you are in Outland and not in combat so that you can shift into Flight Form}
Flight Form / Travel Form / Aquatic Form / Mount (sticky)
/canceform [stance:1/3] [stance:4, nocombat] [stance:5?6, noflying, nocombat]
/use [nostance, outdoors, noflyable, nocombat] ; [nostance, flyable, nocombat]
/cast [nostance, swimming] Aquatic Form; [nostance, flyable, nocombat] Flight Form; [nostance, outdoors] Travel Form
{also: if you have Moonkin Form or Tree of Life, replace "[stance:1/3]" with "[stance:1/3/5]"}
{also: for spamming, remove "[stance:1/3]" from the /cancelform line}
{also: for spamming only while flying (for quick descent), remove "noflying" from the end of the /cancelform line}
{also: for more control when mounting, add "modifier" inside the /use line condition list, and add "/dismount" to the top}
{note: this will take you out of Travel Form if you are in Outland and not in combat so that you can shift into Flight Form}
Travel Form & Rejuvenation (spamable)
/cancelform
/castsequence [nostance, target=player] reset=10 Rejuvenation, Travel Form, Travel Form, Travel Form
Travel Form & Nature's Grasp (spamable)
/cancelform
/castsequence [nostance, outdoors] reset=50 Nature's Grasp, Travel Form, Travel Form, Travel Form
Moonkin / Tree of Life + Change Actionbar
/cancelform [nostance:5]
/cast [nostance]
/changeactionbar [stance:5] 2
{note: since most spells don't work in these forms, this macro sets up a dedicated actionbar with form-specific spells}
Caster Form + Restore Main Actionbar
/cancelform
/changeactionbar [nostance] 1
Dire Bear Form / Cat Form / Moonkin Form / Tree of Life / Flight Form / Travel Form / Aquatic Form
/cancelform
/cast [modifier:ctrl] Cat form; [modifier:alt] Dire Bear Form; [modifier:shift] ; [swimming] Aquatic Form; [flyable, nocombat] Flight Form; [outdoors] Travel Form
Read more...
